/*
	画面スクリプトサンプル
	セーブロード画面

	■外部から設定される変数
	$800　セーブ・ロード画面タイプ 0:セーブ画面 1:ロード画面
	$801　セーブ・ロード画面モード 0:ロードのみ 1:セーブ＆ロード
	$802　現在のページ
	$803　最大ページ

	■セーブデータ内情報（シーンスクリプト内で設定される情報）
	$0　　ゲーム内時間（月）
	$1　　ゲーム内時間（日）

*/

#INCLUDE
	motion.h


///////////////////////////////////////
// 先読みファイル定義 (イメージのみ)
#PRELOAD
	sys_sl_base				// セーブ・ロード画面基本画像
	sys_sl_font_pnow		// 現在のページ番号
	sys_sl_font_pmax		// 最大ページ番号
	sys_sl_font_date		// セーブ日時（リアル時間）用数字フォント
	sys_sl_panel			// セーブパネル画像
	sys_sl_font_gdate_ex	// ゲーム内特殊日時
	sys_sl_font_gdate_n		// ゲーム内日時
	sys_sl_font_gdate_w		// ゲーム内曜日
	sys_userfont			// セーブ時文章用ユーザーフォント


///////////////////////////////////////
// オブジェクト作成
#DEFINE
	CPLANE		topmask		// ホワイトアウト用の真っ白なプレーン
	CIMAGE		basemask	// スクリプト間のつなぎ用白画像ベースイメージ用

	PLANE		pl			// 表示用プレーン

	IMAGE		img_bg		// 背景画像

	IMAGE		img_quick	// Ｑセーブ領域画像
	BUTTON		btn_quick	// Ｑセーブ領域認識用ボタン
	IMAGE		img_quick_w	// Ｑセーブワーニング画像

	BUTTON		btn_sys[7]		// システムボタン
	BUTTON		btn_mode[2]		// モード切替ボタン

	IMAGE		img_syshlp[7]	// システムボタンヘルプ画像
	IMAGE		img_modehlp[2]	// モード切替ボタンヘルプ画像

	IMAGE		img_page_n[2]	// 現在ページ番号
	IMAGE		img_page_m[2]	// 最大ページ番号
	SAVEPANEL	data[6]			// データパネル
	BUTTON		btn_data[6]		// データボタン
	IMAGE		dfont_n			// フォント−ゲーム内日時
	IMAGE		dfont_w			// フォント−ゲーム内曜日
	IMAGE		dfont_ex		// フォント−ゲーム内特殊日時
	IMAGE		dfont_r			// フォント−セーブ時間（リアル時間）


///////////////////////////////////////
// オブジェクト初期化

// ホワイトアウト用の真っ白なプレーン
#OBJECT		COLOR		PRI		SIZE	DISP
topmask		0xffffffff	20000	800,600	0

// スクリプト間のつなぎ用白画像ベースイメージ用
#OBJECT		COLOR		SIZE	PRI		DISP	PL
basemask	0xffffffff	800,600	1000	0		pl


// 表示用プレーン
#OBJECT	SIZE	VRAM	PRI		DISP
pl		800,600	0,0		5000	0

// 背景
#OBJECT		FILE		ID.0	ID.1	PRI	PL	DISP
img_bg		sys_sl_base	0		1		40	pl	0

// Ｑセーブ系
#OBJECT		FILE		ID.0	ID.1	PRI	PL
img_quick	sys_sl_base	20		21		50	pl

#OBJECT		FILE		ID.0	PRI	PL	ENABLE
btn_quick	sys_sl_base	1401	300	pl	0

#OBJECT		FILE		ID.0	PRI	PL
img_quick_w	sys_sl_base	1400	350	pl

// システムボタン系
#OBJECT		FILE			PRI	PL	DISP
btn_sys		sys_sl_base		60	pl	0
btn_mode	sys_sl_base		70	pl	0

#OBJECT		ID.0	ID.1	ID.2	ID.3
btn_sys[0]	100		200		300		400
btn_sys[1]	101		201		301		401
btn_sys[2]	102		202		302		402
btn_sys[3]	103		203		303		403
btn_sys[4]	104		204		304		404
btn_sys[5]	105		205		305		405
btn_sys[6]	106		206		306		406

btn_mode[0]	110		210		310		410
btn_mode[1]	111		211		311		411

// ボタンヘルプ系
#OBJECT		FILE		PRI	PL	DISP
img_syshlp	sys_sl_base	80	pl	0
img_modehlp	sys_sl_base	90	pl	0

#OBJECT			ID.0	ID.1
img_syshlp[0]	500
img_syshlp[1]	501
img_syshlp[2]	502
img_syshlp[3]	503
img_syshlp[4]	504
img_syshlp[5]	505		515		// ID1はロード画面用
img_syshlp[6]	506

img_modehlp[0]	507
img_modehlp[1]	508

// フォント系
#OBJECT		FILE				PRI		PL	DISP
img_page_n	sys_sl_font_pnow	100		pl	0
img_page_m	sys_sl_font_pnow	105		pl	0

dfont_n		sys_sl_font_gdate_n
dfont_w		sys_sl_font_gdate_w
dfont_ex	sys_sl_font_gdate_ex
dfont_r		sys_sl_font_date

#OBJECT			POS2
img_page_n[0]	sys_sl_base:1303
img_page_n[1]	sys_sl_base:1302
img_page_m[0]	sys_sl_base:1301
img_page_m[1]	sys_sl_base:1300

// データパネル
#OBJECT	FILE			PL	DISP	PRI
data	sys_sl_panel	pl	0		200

#OBJECT	POS2
data[0]	sys_sl_base:1100
data[1]	sys_sl_base:1101
data[2]	sys_sl_base:1102
data[3]	sys_sl_base:1103
data[4]	sys_sl_base:1104
data[5]	sys_sl_base:1105

// データボタン
#OBJECT		FILE		PRI	ENABLE	DISP
btn_data	sys_sl_base	220	0		0

#OBJECT		ID.0
btn_data[0]	1200
btn_data[1]	1201
btn_data[2]	1202
btn_data[3]	1203
btn_data[4]	1204
btn_data[5]	1205



// キーボード・ジョイパッド入力設定
#KEYBLOCK	3	//(w,h)	上,下,左,右
0				5,1		-1,1,-1,-1
1				2,3		0,2,-1,-1
2				4,1		1,-1,-1,-1

#OBJECT		KEYBLOCK	// (block,x,y)
btn_sys[0]	0,0,0
btn_sys[1]	0,1,0
btn_sys[2]	0,2,0
btn_sys[3]	0,3,0
btn_sys[4]	0,4,0

btn_data[0]	1,0,0
btn_data[1]	1,0,1
btn_data[2]	1,0,2
btn_data[3]	1,1,0
btn_data[4]	1,1,1
btn_data[5]	1,1,2

btn_sys[5]	2,2,0
btn_sys[6]	2,3,0
btn_mode[0]	2,0,0
btn_mode[1]	2,1,0



///////////////////////////
// スタート
#START
	// 画面構成の設定
	\100 = 6	// １画面のセーブパネルの数
	\101 = 3	// クイックセーブの数

	// キー入力による演出スキップをOFF
	keyskip off
	wait

	// 最新セーブデータの番号を取得
	call GET_NEWDATA

	// 最新データがあるページの番号を算出 → 現在のページとする
	if( \110 >= 0 )
		// １ページ目の先頭にＱデータがあるので、Ｑデータ数分足してます
		$802 = (\110+\101) / \100
	else
		$802 = 0
	endif

	// 最新データがページ内の何番目のパネルか（起動時カーソル自動移動用）
	if( \110 == -1 )
		\109 = -1	// 最新無し
	else
		\109 = (\110+\101) % \100
	endif

	// 上の計算ではページ番号が0〜なので、1を足して1〜にする
	$802++

	// タイトル画面から呼ばれた場合は真っ白プレーンで覆う
	if( $801 == 0 )
		// タイトル画面からの処理
		topmask disp 1	// 真っ白プレーンを表示
		baseimg			// 白のベースイメージを削除
	else
		// シーンからの処理
		// 黒画面からなので特になにもしない
	endif

	// カーソルがボタン以外の場所にあった時に矢印キーが押された場合の
	// 移動先ボタンの設定
	btn_data[0] noact 1		// 左上のデータパネル

	// データパネル設定へ移行
	next INITPANEL


///////////////////////////
// データパネル初期化
#INITPANEL
	// パネルウィンドウ
	data ptype NORM 0	// データ無し用パネル
	data ptype NORM 1	// データ有り用パネル
	data ptype NORM 2	// フォーカス時用カーソル

	// 日付用装飾
	data ptype NORM 3	// 日付有り・曜日有り
	data ptype NORM 13	// 日付有り・曜日無し
	data ptype NORM 4	// 日付無し・曜日無し（特殊用）

	// サムネイル
	data ptype NORM 5	// サムネイル枠
	data ptype SIMAGE 10 0x100	// サムネイル

	// 最新マーク
	data ptype NORM 6	// 通常データ用
	data ptype NORM 7	// Ｑデータ用

	// ゲーム内日時
	data ptype NUM_O2 50 dfont_n FLAG.1	// 月
	data ptype NUM_O2 51 dfont_n FLAG.2	// 日
	data ptype NUM_O2 52 dfont_w FLAG.3	// 曜日

	data ptype SSTR 12 0x200 14 11 0xffffffff 3 0xff404040 2 3	// セーブ時のテキスト

	// セーブ年
	data ptype NUM_O2 100 dfont_r DATE_Y:1000
	data ptype NUM_O2 101 dfont_r DATE_Y:100
	data ptype NUM_O2 102 dfont_r DATE_Y:10
	data ptype NUM_O2 103 dfont_r DATE_Y:1

	// セーブ月
	data ptype NUM_O2 110 dfont_r DATE_M:10
	data ptype NUM_O2 111 dfont_r DATE_M:1

	// セーブ日
	data ptype NUM_O2 120 dfont_r DATE_D:10
	data ptype NUM_O2 121 dfont_r DATE_D:1

	// セーブ時
	data ptype NUM_O2 130 dfont_r DATE_H:10
	data ptype NUM_O2 131 dfont_r DATE_H:1

	// セーブ分
	data ptype NUM_O2 140 dfont_r DATE_N:10
	data ptype NUM_O2 141 dfont_r DATE_N:1

	// ユーザーフォント設定
	data userfont 12 sys_userfont 0x8740 1
	data userfont 12 sys_userfont 0x8741 2
	data userfont 12 sys_userfont 0x8742 3
	data userfont 12 sys_userfont 0x8743 4
	data userfont 12 sys_userfont 0x8744 5
	data userfont 12 sys_userfont 0x8744 6
	data userfont 12 sys_userfont 0x8744 7
	data userfont 12 sys_userfont 0x8744 8
	data userfont 12 sys_userfont 0x8744 9

	// 背景の設定へ移行
	next SETBG


///////////////////////////
// 背景セット
#SETBG
	// $800 : セーブの時>0 ロードの時>1
	img_bg setid $800		// 背景
	img_quick setid $800	// Ｑデータ領域パネル
	img_syshlp[5] setid $800	// ヘルプ

	// データ設定へ移行
	next SETDATA


///////////////////////////
// データパネル設定
#SETDATA
	wait 1

	// ページ
	img_page_n[0] setid $802/10		// 現在のページ（１０の位）
	img_page_n[1] setid $802%10		// 現在のページ（１の位）
	img_page_m[0] setid $803/10		// 最大ページ（１０の位）
	img_page_m[1] setid $803%10		// 最大ページ（１の位）

	// 「クイックセーブ」パネルを表示するかどうかチェック
	if( $802 == 1 )
		// １ページ目だったらＱデータ領域ウィンドウを表示
		img_quick disp 1
	else
		// ２メージ目以降ならＱデータ領域ウィンドウを非表示
		img_quick disp 0
	endif

	\108 = 0	// ループカウンタ
	next SETDATA_2	// パネル個別設定へ


///////////////////////////
// セーブデータが存在するか確認しながらパネルをセットするループ
#SETDATA_2
	// １ページの範囲を超えたらループを抜ける
	if( \108 >= \100 )	next BTNINIT	// ボタン設定へ移行

	// セーブデータ番号 ((ページNo-1) * １ページ当たりのデータ数 + ページ内のデータNo)
	\120 = ($802-1) * \100 + \108

	// Ｑセーブチェック
	// データ番号がＱセーブ数未満の場合はＱセーブとする
	if( \120 < \101 )
		// Ｑデータの場合
		\120 += 5000	// Ｑデータは5000から始まるので5000を足す
	else
		// 通常データの場合
		\120 -= \101	// Ｑデータ数分が加算されている状態なので、その分を減算
	endif

	// セーブデータが存在するかをチェック
	saveexist \120 850
	\(200+\108) = $850	// \200〜に存在状態をセット

	// セーブデータ有り無しに関わらずデータをセットしないとSAVEPANELは画像を表示しないため
	// ここでセット
	data[\108] setsave \120 0x00000400 0

	if( \(200+\108) == 0 )
		// データが無い場合
		call SETDATA_NODATA
	else
		// データがある場合
		call SETDATA_EXIST
	endif

	// カウンタを進ませてループ先頭へ
	\108++
	next SETDATA_2


///////////////////////////
// データパネルセット(データなし)
#SETDATA_NODATA
	// データ無し用ウィンドウを表示
	data[\108] dispid 1 0

	// その他を非表示
	data[\108] dispid 0 [1-150]


///////////////////////////
// データパネルセット(データ有り)
#SETDATA_EXIST
	data[\108] dispid 0 0	// データ無し用ウィンドウは非表示
	data[\108] dispid 0 2	// カーソルも非表示にしておく

	// 表示するもの
	data[\108] dispid 1 1 5	10 12	// データ有りウィンドウとサムネイルと文章
	data[\108] dispid 1 [100-150]	// セーブ時日時（リアル時間）

	// 最新状態チェック
	data[\108] dispid 0 6 7		// とりあえず最新マークを非表示に設定
	if( \110 == \120 )
		// 通常データの最新データの場合は『最新』マークを表示
		data[\108] dispid 1 6
	endif
	if( \111 == \120 )
		// Ｑデータの最新データの場合はＱデータ用『最新』マークを表示
		data[\108] dispid 1 7
	endif

	// ゲーム内日付によって表示するものを変更
	data[\108] getflag 0 850
	if( $850 >= 100 )
		// 月が100以上なら特殊日時とする
		$850 -= 100		// 100を引いた値を特殊日時画像IDとする
		// 特殊日時を設定
		data[\108] ptype NUM_O2 53 dfont_ex $850
		data[\108] dispid 1 53	// そして表示

		// 通常日付用のものは非表示にする
		data[\108] dispid 0 3 13
		data[\108] dispid 0 [50-52]
	else
		// 通常日付の場合
		data[\108] dispid 1 3			// 日 月 （ ） 画像を表示
		data[\108] dispid 1 [50-52]		// 日付表示

		// 特殊日付用のものは非表示にする
		data[\108] dispid 0 4 13	// 特殊日付用と曜日なし表示用を非表示
		data[\108] dispid 0 53		// 特殊日付
	endif

	// ptypeによる設定の変更を行ったため、再度セーブデータを設定して更新する
	data[\108] setsave \120 0x00000400 0



///////////////////////////
// ボタン初期化
#BTNINIT
	wait 1

	// ボタン有効化
	
	// システム系ボタン
	btn_sys enable 1
	btn_sys setid 0		// モード切り替え時等にボタン色が押下色になったままになったりするので
						// ここでボタン色を元に戻しておく

	// データボタン
	btn_data enable 1

	// 戻る・進むボタン
	if( $802 == 1 )
		// １ページ目の時
		btn_sys[1] setid 1		// 『戻る』を無効色に
		btn_sys[1] enable 0		// そして無効化
		btn_sys[2] setid 1
		btn_sys[2] enable 0
	endif

	if( $802 == $803 )
		// 最終ページの時
		btn_sys[3] setid 1
		btn_sys[3] enable 0
		btn_sys[4] setid 1
		btn_sys[4] enable 0
	endif

	if( ($803==99) || ($800==1) )
		// ページ追加が出来ない場合はページ追加ボタンを非表示
		btn_sys[0] setid 1
		btn_sys[0] enable 0
	endif

	// セーブ・ロード切り替えボタン有効化
	btn_mode enable 1

	// Ｑデータ注意書き表示用領域判定を無効化
	btn_quick enable 0

	// システム系ボタン表示
	btn_sys disp 1

	// ボタン表示
	btn_mode disp 1

	if( $800 == 0 )
		// セーブの時
		btn_mode[0] disp 1	// 『ロード画面へ』ボタンを表示
		btn_mode[1] disp 0	// 『セーブ画面へ』ボタンは非表示
		btn_mode[1] enable 0	// セーブ無効化
		if( $803 == 1 )
			// 先頭ページの場合
			btn_quick enable 1	// Ｑデータ注意書きを表示する為、領域判定を有効化
		endif
	endif
	if( $800 == 1 )
		// ロードの時
		btn_mode[0] disp 0	// 『ロード画面へ』ボタンは非表示
		btn_mode[0] enable 0	// ロード無効化
		
		if( $801 == 0 )
			// タイトル画面からの場合
			btn_mode[1]	setid 1	// 『セーブ画面へ』ボタンはグレー表示
			btn_mode[1] enable 0	// セーブ無効化
		else
			// ゲーム中からの場合
			btn_mode[1] disp 1	// 『セーブ画面へ』ボタンを表示
		endif
	endif

	// ヘルプ非表示
	img_syshlp disp 0
	img_modehlp disp 0

	// Ｑデータ注意書き非表示
	img_quick_w disp 0

	// 背景表示
	img_bg disp 1

	// パネルを表示
	data disp 1

	// ページ番号表示
	img_page_n disp 1
	img_page_m disp 1


	// 表示演出
	if( \107 == 0 )	// 画面(スクリプト)が呼ばれたばかりのとき
		pl disp 1			// プレーンを表示させる
		if( $801 == 0 )
			// タイトル画面からの処理
			topmask fade 16 255 0	// 真っ白プレーンをフェードアウト
		else
			// シーンからの処理
			pl fade 16 0 255		// 表示用プレーンをフェードイン
		endif
		if( \109 >= 0 )
			// 最新データがある場合はそのパネルにカーソルを自動移動
			automove btn_data[\109]
		endif
	endif

	// 実行済みフラグを立てる
	\107 = 1

	// 入力待ちへ移行
	next WAIT


///////////////////////////
// 入力待ち
#WAIT
	// 右クリックで戻る
	if(_CLICK_R_ != 0 )	next EXIT

	// キーボード[Page Up] 又は マウスホイール[↑]
	if( _PAGE_U_ != 0 )
		if( $802 > 1 )	// 先頭ページ以外の場合
			// １ページ戻る
			$802--
			next SETDATA
		endif
	endif

	// キーボード[Page Down] 又は マウスホイール[↓]
	if( _PAGE_D_ != 0 )
		if( $802 < $803 )	// 最終ページ以外の場合
			// １ページ進む
			$802++
			next SETDATA
		endif
	endif



///////////////////////////
// セーブ画面へ
#GO_SAVE
	$800 = 0	// セーブモードに変更
	next SETBG	// 背景設定（セーブ・ロード変更）へ移行


///////////////////////////
// ロード画面へ
#GO_LOAD
	$800 = 1	// ロードモードへ変更
	next SETBG	// 背景設定（セーブ・ロード変更）へ移行


///////////////////////////
// ページ追加
#ADDPAGE
	if( $803 < 99 )
		$803++
		// 最大ページ数更新
		img_page_m[0] setid $803/10
		img_page_m[1] setid $803%10
	endif

	// ボタン初期化へ移行
	next BTNINIT


///////////////////////////
// スクリプト終了（戻るボタン）
#EXIT
	// 全てのボタンを無効化
	call DISABLE_ALLBTN

	if( $801 == 0 )
		// タイトル画面からの処理
		topmask fade 16 0 255	// 真っ白プレーンをフェードアウト
	else
		// シーンからの処理
		pl fade 16 255 0		// 表示用プレーンをフェードイン
	endif
	wait

	// タイトル画面からの場合は白画像をベースイメージに設定
	if( $801 == 0 )	baseimg basemask

	// 終了
	exit -2
	next SLEEP


///////////////////////////
// ゲーム終了（終了ボタン）
#QUIT
	// 終了確認ダイアログを実行
	$860 = 0
	execfes conf
	next QUIT_WAIT


///////////////////////////
// ゲーム終了確認待ち
#QUIT_WAIT
	if( _EXITCODE_ == 1 )
		call DISABLE_ALLBTN		// すべてのボタンを無効化
		endfes		// ダイアログスクリプト終了
		next QUIT2	// ゲーム終了処理へ
	endif
	if( _EXITCODE_ == 0 )
		endfes		// ダイアログスクリプト終了
		resetactive	// ボタン再アクティブ化
		next WAIT	// 入力待ちへ戻る
	endif


///////////////////////////
// ゲーム終了2
#QUIT2
	// フェードアウトしてシステム終了
	pl fade 30 255 0
	wait
	exit -3
	next SLEEP


///////////////////////////
// 上書き確認
#CONFIRM
	$860 = 1
	execfes conf
	wait 1
	next CONFIRM_WAIT


///////////////////////////
// 上書き確認待ち
#CONFIRM_WAIT
	if( _EXITCODE_ == 1 )
		// 『はい』が選ばれた場合
		endfes			// ダイアログスクリプトを終了
		next SAVEDATA	// セーブ処理へ
	endif
	if( _EXITCODE_ == 0 )
		// 『いいえ』が選ばれた場合
		endfes			// ダイアログスクリプトを終了
		resetactive		// ボタン再アクティブ化
		next WAIT		// 入力待ちへ
	endif


///////////////////////////
// データセーブ
#SAVEDATA
	// セーブ実行
	// \130 はセーブデータ番号
	// _SAVEOBJ_ はセーブ用の特殊変数です。
	datasave \130 _SAVEOBJ_

	// 最新セーブデータ番号を取得
	call GET_NEWDATA

	next SETDATA	// データ設定へ移行


///////////////////////////
// データロード
#LOADDATA
	// 全てのボタンを無効化して...
	call DISABLE_ALLBTN

	// フェードアウト
	pl fade 30 255 0
	wait

	// ロード実行コード(ロードするデータ番号)を指定して終了
	exit \130
	next SLEEP



///////////////////////////
// スクリプト終了後の空ループ
#SLEEP



///////////////////////////
// ボタン処理

// システム系ボタン
#btn_sys.FOCUS
	@ setid 2				// フォーカス色に変更
	img_syshlp[@] disp 1	// ヘルプを表示

#btn_sys.UNFOCUS
	@ setid 0				// 元の色に変更
	img_syshlp[@] disp 0	// ヘルプを消す

#btn_sys.PUSH_L
	@ setid 3				// 押下色に変更

	if( @ == 0 )
		// ページ追加
		next ADDPAGE
	endif
	if( @ == 1 )
		// 先頭ページに戻る
		$802 = 1
		next SETDATA
	endif
	if( @ == 2 )
		// １ページ戻る
		$802--
		next SETDATA
	endif
	if( @ == 3 )
		// １ページ進む
		$802++
		next SETDATA
	endif
	if( @ == 4 )
		// 最終ページに進む
		$802 = $803
		next SETDATA
	endif
	if( @ == 5 )
		// 戻る
		next EXIT
	endif
	if( @ == 6 )
		// ゲーム終了
		next QUIT
	endif


// セーブ・ロード切り替えボタン
#btn_mode.FOCUS
	@ setid 2
	img_modehlp[@] disp 1

#btn_mode.UNFOCUS
	@ setid 0
	img_modehlp[@] disp 0

#btn_mode.PUSH_L
	@ setid 3
	$800 = 1 - $800		// セーブ⇔ロード入れ替え
	next SETBG


// データパネルボタン
#btn_data.FOCUS
	data[@] dispid 1 2

#btn_data.UNFOCUS
	data[@] dispid 0 2

#btn_data.PUSH_L
	// \130 = データ番号
	\130 = ($802-1)*\100 + @

	// データ番号がＱセーブ数未満の場合はＱセーブとする
	if( \130 < \101 )
		// Ｑデータの場合
		\130 += 5000	// Ｑデータは5000から始まるので5000を足す
	else
		// 通常データの場合
		\130 -= \101	// Ｑデータ数分が加算されている状態なので、その分を減算
	endif

	if( $800 == 0 )
		// セーブモードの場合
		if( \(200+@) )
			// セーブデータが既に存在している場合
			next CONFIRM	// 上書き確認へ
		else
			// セーブデータが無い空パネルが選択された場合
			next SAVEDATA	// セーブ処理へ
		endif
	else
		// ロードモードの場合
		if( \(200+@) )
			// セーブデータが既に存在している場合
			next LOADDATA	// ロード処理へ
		endif
	endif


// Ｑデータエリア判定用ボタン
#btn_quick.FOCUS
	img_quick_w disp 1	// 注意パネルを表示

#btn_quick.UNFOCUS
	img_quick_w disp 0	// 注意パネルを消す




///////////////////////////
// 最新セーブデータ番号を取得
#GET_NEWDATA
	// 通常セーブデータの最新を検索
	newsave 850 0 999
	\110 = $850		// 最新セーブデータNoを退避

	// クイックセーブデータの最新を検索
	newsave 851 5000 5000+\101-1
	\111 = $850		// 最新ＱセーブデータNoを退避


///////////////////////////
// ボタン全て無効
#DISABLE_ALLBTN
	btn_sys enable 0
	btn_mode enable 0
	btn_data enable 0
	btn_quick enable 0



