/*
	環境設定
*/

#INCLUDE
	motion.h


#PRELOAD	// 先読みファイル定義 (イメージのみ)
	sys_config
	sys_config_mes
	sys_config_num


#DEFINE
	PLANE		pl			// 表示用プレーン

	IMAGE		img_bg		// 背景画像
	IMAGE		img_help	// ヘルプ画像

	BUTTON		btn_no[5]		// 『しない』or『OFF』ボタン
	BUTTON		btn_yes[5]		// 『する』or『ON』ボタン
	BUTTON		btn_shadow[2]	// 影タイプボタン
	BUTTON		btn_speed[5]	// 演出速度ボタン

	// 『しない』or『OFF』ボタンの画像
	IMAGE		img_no_box[5]		// □
	IMAGE		img_no_word[5]		// 文字部分
	IMAGE		img_no_check[5]		// □の上に付くチェックマーク

	// 『する』or『ON』ボタンの画像
	IMAGE		img_yes_box[5]		// □
	IMAGE		img_yes_word[5]		// 文字部分
	IMAGE		img_yes_check[5]	// □の上に付くチェックマーク

	// 影タイプボタンの画像
	IMAGE		img_shadow_box[2]	// □
	IMAGE		img_shadow_word[2]	// 文字部分
	IMAGE		img_shadow_check[2]	// □の上に付くチェックマーク

	// 演出速度ボタンの画像
	IMAGE		img_speed_box[5]	// □
	IMAGE		img_speed_word[5]	// 文字部分
	IMAGE		img_speed_check[5]	// □の上に付くチェックマーク

	// スライダー系
	SLIDER		sl_mes			// メッセージ速度
	SLIDER		sl_auto			// オート速度
	SLIDER		sl_wndalpha		// ウィンドウ不透明度
	SLIDER		sl_volume[4]	// ボリューム系

	// ウィンドウ不透明度の数値
	IMAGE		num_wndalpha[3]

	// ボリュームの数値
	IMAGE		num_volume_master[3]	// マスター
	IMAGE		num_volume_bgm[3]		// BGM
	IMAGE		num_volume_se[3]		// 効果音
	IMAGE		num_volume_play[3]		// 音声再生時のBGMボリューム

	// システム系ボタン
	BUTTON		btn_sys[2]		// RESETとEXITボタン

	// ヘルプメッセージ
	IMAGE		img_help

	// サンプル文章
	STRING		str_sample[2]




///////////////////////////
// オブジェクト初期化

// 表示用プレーン
#OBJECT	POS		BASE	PRI		VRAM	SIZE	DISP
pl		0,0 	0,0 	5000	0,0		800,600	0

// 背景
#OBJECT	FILE		ID.0	PRI		PL	DISP
img_bg	sys_config	0		50		pl	1


// チェックボタン
#OBJECT		FILE		PRI		DISP	ENABLE
btn_no		sys_config	1000	0		0
btn_yes		sys_config	1100	0		0
btn_shadow	sys_config	1200	0		0
btn_speed	sys_config	1300	0		0

#OBJECT			ID.0
btn_no[0]		1400
btn_no[1]		1401
btn_no[2]		1402
btn_no[3]		1403
btn_no[4]		1404

btn_yes[0]		1410
btn_yes[1]		1411
btn_yes[2]		1412
btn_yes[3]		1413
btn_yes[4]		1414

btn_shadow[0]	1420
btn_shadow[1]	1421

btn_speed[0]	1430
btn_speed[1]	1431
btn_speed[2]	1432
btn_speed[3]	1433
btn_speed[4]	1434


// チェックボタン画像
#OBJECT				FILE		PRI		PL		DISP
img_no_box			sys_config	100		pl		1
img_no_word			sys_config	110		pl		1
img_no_check		sys_config	120		pl		0

img_yes_box			sys_config	130		pl		1
img_yes_word		sys_config	140		pl		1
img_yes_check		sys_config	150		pl		0

img_shadow_box		sys_config	160		pl		1
img_shadow_word		sys_config	170		pl		1
img_shadow_check	sys_config	180		pl		0

img_speed_box		sys_config	190		pl		1
img_speed_word		sys_config	200		pl		1
img_speed_check		sys_config	210		pl		0



#OBJECT				ID.0	ID.1	ID.2	ID.3
img_no_box[0]		1000	1001	1002	1003
img_no_word[0]		1005	1006	1007	1008
img_no_check[0]		1009

img_no_box[1]		1010	1011	1012	1013
img_no_word[1]		1015	1016	1017	1018
img_no_check[1]		1019

img_no_box[2]		1020	1021	1022	1023
img_no_word[2]		1025	1026	1027	1028
img_no_check[2]		1029

img_no_box[3]		1030	1031	1032	1033
img_no_word[3]		1035	1036	1037	1038
img_no_check[3]		1039

img_no_box[4]		1040	1041	1042	1043
img_no_word[4]		1045	1046	1047	1048
img_no_check[4]		1049

img_yes_box[0]		1100	1101	1102	1103
img_yes_word[0]		1105	1106	1107	1108
img_yes_check[0]	1109

img_yes_box[1]		1110	1111	1112	1113
img_yes_word[1]		1115	1116	1117	1118
img_yes_check[1]	1119

img_yes_box[2]		1120	1121	1122	1123
img_yes_word[2]		1125	1126	1127	1128
img_yes_check[2]	1129

img_yes_box[3]		1130	1131	1132	1133
img_yes_word[3]		1135	1136	1137	1138
img_yes_check[3]	1139

img_yes_box[4]		1140	1141	1142	1143
img_yes_word[4]		1145	1146	1147	1148
img_yes_check[4]	1149

img_shadow_box[0]	1200	1201	1202	1203
img_shadow_word[0]	1205	1206	1207	1208
img_shadow_check[0]	1209

img_shadow_box[1]	1210	1211	1212	1213
img_shadow_word[1]	1215	1216	1217	1218
img_shadow_check[1]	1219

img_speed_box[0]	1300	1301	1302	1303
img_speed_word[0]	1305	1306	1307	1308
img_speed_check[0]	1309

img_speed_box[1]	1310	1311	1312	1313
img_speed_word[1]	1315	1316	1317	1318
img_speed_check[1]	1319

img_speed_box[2]	1320	1321	1322	1323
img_speed_word[2]	1325	1326	1327	1328
img_speed_check[2]	1329

img_speed_box[3]	1330	1331	1332	1333
img_speed_word[3]	1335	1336	1337	1338
img_speed_check[3]	1339

img_speed_box[4]	1340	1341	1342	1343
img_speed_word[4]	1345	1346	1347	1348
img_speed_check[4]	1349


// スライダー
#OBJECT			FILE				POS2			PRI	DISP
sl_mes			sys_config_gauge	sys_config:2000	300	1
sl_auto			sys_config_gauge	sys_config:2001	301	1
sl_wndalpha		sys_config_gauge	sys_config:2002	302	1
sl_volume[0]	sys_config_gauge	sys_config:2003	303	1
sl_volume[1]	sys_config_gauge	sys_config:2004	304	1
sl_volume[2]	sys_config_gauge	sys_config:2005	305	1
sl_volume[3]	sys_config_gauge	sys_config:2006	306	1


// スライダー用数値
#OBJECT				FILE			PRI	PL	DISP
num_wndalpha		sys_config_num	400	pl	0
num_volume_master	sys_config_num	410	pl	0
num_volume_bgm		sys_config_num	420	pl	0
num_volume_se		sys_config_num	430	pl	0
num_volume_play		sys_config_num	440	pl	0

#OBJECT					POS2
num_wndalpha[0]			sys_config:420
num_wndalpha[1]			sys_config:421
num_wndalpha[2]			sys_config:422
num_volume_master[0]	sys_config:430
num_volume_master[1]	sys_config:431
num_volume_master[2]	sys_config:432
num_volume_bgm[0]		sys_config:440
num_volume_bgm[1]		sys_config:441
num_volume_bgm[2]		sys_config:442
num_volume_se[0]		sys_config:450
num_volume_se[1]		sys_config:451
num_volume_se[2]		sys_config:452
num_volume_play[0]		sys_config:460
num_volume_play[1]		sys_config:461
num_volume_play[2]		sys_config:462


// システム系ボタン
#OBJECT		FILE		ID.0	ID.1	ID.2	ID.3	PRI	PL	DISP	ENABLE
btn_sys[0]	sys_config	600		601		602		603		500	pl	1		0
btn_sys[1]	sys_config	610		611		612		613		501	pl	1		0


// ヘルプメッセージ
#OBJECT		FILE			POS2			PRI	PL	DISP
img_help	sys_config_mes	sys_config:500	600	pl	0


// スピードサンプル文章
#OBJECT			VRAM		POS2			SIZE2			PRI
str_sample[0]	512,2504	sys_config:3000	sys_config:3000	6000
str_sample[1]	512,2534	sys_config:3001	sys_config:3001	6000




///////////////////////////
// スタート
#START
	// キー入力による演出スキップをOFF
	keyskip off
	wait

	// スライダーの設定
	sl_mes page 0 10
	sl_auto page 0 10
	sl_wndalpha page 0 100
	sl_volume page 0 100

	// 環境設定取得
	call GET_CONFIG

	// 設定を反映
	call SET_YESNO_BUTTON		// Yes/Noボタンの設定
	call SET_SHADOW_BUTTON		// 影タイプボタンの設定
	call SET_EFF_SPEED_BUTTON	// 演出速度ボタンの設定
	call SET_SLIDER				// スライダー系の設定

	// 数値設定
	call SET_SLIDER_NUM

	// サンプル文章設定
	call STRLAYOUT
	strvar 150 \pcＣＳ２システム
	strvar 151 \pcＣＳ２システム

	// 表示
	pl disp 1			// プレーンを表示させて
	pl fade 30 0 255	// フェードイン

	// サンプル文章を表示
	str_sample disp 1
	call DRAW_SAMPLE_MESSPEED
	call DRAW_SAMPLE_AUTOSPEED

	// ボタン有効化
	call ENABLE_BUTTON

	next WAIT	// 入力待ちループへ


///////////////////////////
// 入力待ちループ
#WAIT
	// 右クリックで戻る
	if(_CLICK_R_ != 0 )	next EXIT

	// サンプル文章再描画処理
	// メッセージ速度
	if( \200 > 0 )	// 最速以外なら処理する（最速は再描画の必要無し）
		if( \300 <= _FRAME_ )
			// 更新時間を過ぎていたら更新
			call DRAW_SAMPLE_MESSPEED
		endif
	endif
	// オート速度
	if( \301 <= _FRAME_ )
		// 更新時間を過ぎていたら更新
		call DRAW_SAMPLE_AUTOSPEED
	endif


///////////////////////////
// 環境設定終了
#EXIT
	// ボタンを全て無効化
	call DISABLE_BUTTON

	// 環境設定に設定を適用
	call SET_CONFIG
	wait

	// フェードアウト
	pl[0] fade 30 255 0
	str_sample fade 30 255 0	// サンプル文章もフェードアウト
	wait

	// 終了
	exit 0
	next SLEEP


///////////////////////////
// スクリプト終了後の空ループ
#SLEEP



///////////////////////////
// 環境設定を取得
#GET_CONFIG
	// 文章表示速度
	getconf 850 messpd
	\200 = $850

	// オート速度
	getconf 850 autospd
	\201 = $850

	// オート速度の詳細設定−基本待ち時間
	getconf 850 autospd_b
	\202 = $850

	// オート速度の詳細設定−１文字あたりの待ち時間
	getconf 850 autospd_c
	\203 = $850

	// オートの時、オートスピードに関わらず音声再生が終了するまで待つか
	getconf 850 waitpcm
	\204 = $850

	// 既読メッセージの瞬間表示
	getconf 850 stillread
	\205 = $850

	// 選択肢後もオートを継続するか
	getconf 850 contauto
	\206 = $850

	// メッセージウィンドウの不透明度
	getconf 850 wndcolor
	\207 = $850 >> 24

	// 文字の影（影）
	getconf 850 fshadow 0
	\208 = $850

	// 文字の影（縁）
	getconf 850 fshadow 1
	\209 = $850

	// 演出速度
	getconf 850 effspd
	\210 = $850

	// 演出カット
	getconf 850 effcut
	\211 = $850

	// ドラマチックモード
	getconf 850 dorama
	\212 = $850

	// ボリューム−マスター
	getconf 850 vol_master
	\213 = $850

	// ボリューム−BGM
	getconf 850 vol_bgm
	\214 = $850

	// ボリューム−効果音
	getconf 850 vol_se
	\215 = $850

	// ボリューム−音声
	getconf 850 vol_voice
	\216 = $850

	// ボリューム−音声再生時のBGMボリューム
	getconf 850 vol_play
	\217 = $850


///////////////////////////
// 環境設定を適用
#SET_CONFIG
	// 文章表示速度
	setconf \200 messpd

	// オート速度
	setconf \201 autospd

	// オート速度の詳細設定−基本待ち時間
//	setconf \202 autospd_b	// オート速度を設定すると自動設定されるので、必要ないです

	// オート速度の詳細設定−１文字あたりの待ち時間
//	setconf \203 autospd_c	// オート速度を設定すると自動設定されるので、必要ないです

	// オートの時、オートスピードに関わらず音声再生が終了するまで待つか
	setconf \204 waitpcm

	// 既読メッセージの瞬間表示
	setconf \205 stillread

	// 選択肢後もオートを継続するか
	setconf \206 contauto

	// メッセージウィンドウの不透明度
	setconf (\207<<24) wndcolor

	// 文字の影（影）
	setconf \208 fshadow 0

	// 文字の影（縁）
	setconf \209 fshadow 1

	// 演出速度
	setconf \210 effspd

	// 演出カット
	setconf \211 effcut

	// ドラマチックモード
	setconf \212 dorama

	// ボリューム−マスター
	setconf \213 vol_master

	// ボリューム−BGM
	setconf \214 vol_bgm

	// ボリューム−効果音
	setconf \215 vol_se

	// ボリューム−音声
	setconf \216 vol_voice

	// ボリューム−音声再生時のBGMボリューム
	setconf \217 vol_play


///////////////////////////
// Yes/Noボタンの設定
#SET_YESNO_BUTTON
	img_no_check disp 0
	img_yes_check disp 0

	// 音声を最後まで再生
	if( \204 )
		img_yes_check[0] disp 1
	else
		img_no_check[0] disp 1
	endif

	// 既読メッセージの瞬間表示
	if( \205 )
		img_yes_check[1] disp 1
	else
		img_no_check[1] disp 1
	endif

	// 選択肢後のオートモード継続
	if( \206 )
		img_yes_check[2] disp 1
	else
		img_no_check[2] disp 1
	endif

	// 画面切り替えの瞬間表示
	if( \211 )
		img_yes_check[3] disp 1
	else
		img_no_check[3] disp 1
	endif

	// ドラマチックモード
	if( \212 )
		img_yes_check[4] disp 1
	else
		img_no_check[4] disp 1
	endif


///////////////////////////
// 影ボタンの設定
#SET_SHADOW_BUTTON
	img_shadow_check disp 0

	if( \208 )
		img_shadow_check[0] disp 1
	endif

	if( \209 )
		img_shadow_check[1] disp 1
	endif


///////////////////////////
// 演出速度ボタンの設定
#SET_EFF_SPEED_BUTTON
	img_speed_check disp 0

	img_speed_check[\210] disp 1


///////////////////////////
// スライダー系の設定
#SET_SLIDER
	sl_mes pos 10-\200
	sl_auto pos 10-\201
	sl_wndalpha pos \207
	sl_volume[0] pos \213
	sl_volume[1] pos \214
	sl_volume[2] pos \215
	sl_volume[3] pos \217


///////////////////////////
// スライダー系の数値の設定
#SET_SLIDER_NUM
	// とりあえず全ての桁を表示状態にする
	num_wndalpha disp 1
	num_volume_master disp 1
	num_volume_bgm disp 1
	num_volume_se disp 1
	num_volume_play disp 1

	// ウィンドウの不透明度
	\0 = \207
	num_wndalpha[2] settbl 0 \0/100		// 100の位をセット
	if( \0/100 == 0 )	num_wndalpha[2] disp 0	// 100の位が0なら非表示
	\1 = \0 % 100
	num_wndalpha[1] settbl 0 \1/10		// 10の位をセット
	if( \0/100 == 0 && \1/10 == 0 )	num_wndalpha[1] disp 0	// 100の位と10の位が0なら非表示
	\2 = \1 % 10
	num_wndalpha[0] settbl 0 \2			// 1の位をセット

	// ボリューム−マスター
	\0 = \213
	num_volume_master[2] settbl 0 \0/100
	if( \0/100 == 0 )	num_volume_master[2] disp 0
	\1 = \0 % 100
	num_volume_master[1] settbl 0 \1/10
	if( \0/100 == 0 && \1/10 == 0 )	num_volume_master[1] disp 0
	\2 = \1 % 10
	num_volume_master[0] settbl 0 \2

	// ボリューム−BGM
	\0 = \214
	num_volume_bgm[2] settbl 0 \0/100
	if( \0/100 == 0 )	num_volume_bgm[2] disp 0
	\1 = \0 % 100
	num_volume_bgm[1] settbl 0 \1/10
	if( \0/100 == 0 && \1/10 == 0 )	num_volume_bgm[1] disp 0
	\2 = \1 % 10
	num_volume_bgm[0] settbl 0 \2

	// ボリューム−効果音
	\0 = \215
	num_volume_se[2] settbl 0 \0/100
	if( \0/100 == 0 )	num_volume_se[2] disp 0
	\1 = \0 % 100
	num_volume_se[1] settbl 0 \1/10
	if( \0/100 == 0 && \1/10 == 0 )	num_volume_se[1] disp 0
	\2 = \1 % 10
	num_volume_se[0] settbl 0 \2

	// ボリューム−音声再生時のBGMボリューム
	\0 = \217
	num_volume_play[2] settbl 0 \0/100
	if( \0/100 == 0 )	num_volume_play[2] disp 0
	\1 = \0 % 100
	num_volume_play[1] settbl 0 \1/10
	if( \0/100 == 0 && \1/10 == 0 )	num_volume_play[1] disp 0
	\2 = \1 % 10
	num_volume_play[0] settbl 0 \2

	// この段階ではまだ ID.0 に値を設定しただけで表示更新されない
	// なので、setid で表示更新をする
	num_wndalpha setid 0
	num_volume_master setid 0
	num_volume_bgm setid 0
	num_volume_se setid 0
	num_volume_play setid 0



///////////////////////////
// ボタンの有効化
#ENABLE_BUTTON
	btn_no enable 1		// 『しない』or『OFF』ボタン
	btn_yes enable 1	// 『する』or『ON』ボタン
	btn_shadow enable 1	// 影タイプボタン
	btn_speed enable 1	// 演出速度ボタン

	sl_mes enable 1			// メッセージ速度
	sl_auto enable 1		// オート速度
	sl_wndalpha enable 1	// ウィンドウ不透明度
	sl_volume enable 1		// ボリューム

	btn_sys enable 1	// システム系ボタン


///////////////////////////
// ボタンの無効化
#DISABLE_BUTTON
	btn_no enable 0		// 『しない』or『OFF』ボタン
	btn_yes enable 0	// 『する』or『ON』ボタン
	btn_shadow enable 0	// 影タイプボタン
	btn_speed enable 0	// 演出速度ボタン

	sl_mes enable 0			// メッセージ速度
	sl_auto enable 0		// オート速度
	sl_wndalpha enable 0	// ウィンドウ不透明度
	sl_volume enable 0		// ボリューム

	btn_sys enable 0	// システム系ボタン


///////////////////////////
// ボタン処理

// 『しない』/『OFF』系
#btn_no.FOCUS
	img_no_box[@] setid 2
	img_no_word[@] setid 2
	
	// ヘルプ表示
	if( @ == 0 )	img_help settbl 0 1
	if( @ == 1 )	img_help settbl 0 3
	if( @ == 2 )	img_help settbl 0 5
	if( @ == 3 )	img_help settbl 0 13
	if( @ == 4 )	img_help settbl 0 15
	img_help setid 0
	img_help disp 1

#btn_no.UNFOCUS
	img_no_box[@] setid 0
	img_no_word[@] setid 0
	img_help disp 0

#btn_no.PUSH_L
	img_no_box[@] setid 3
	img_no_word[@] setid 3
	if( @ == 0 )	\204 = 0
	if( @ == 1 )	\205 = 0
	if( @ == 2 )	\206 = 0
	if( @ == 3 )	\211 = 0
	if( @ == 4 )	\212 = 0
	call SET_YESNO_BUTTON

#btn_no.RELEASE_L
	img_no_box[@] setid 2
	img_no_word[@] setid 2


// 『する』/『ON』系
#btn_yes.FOCUS
	img_yes_box[@] setid 2
	img_yes_word[@] setid 2

	// ヘルプ表示
	if( @ == 0 )	img_help settbl 0 0
	if( @ == 1 )	img_help settbl 0 2
	if( @ == 2 )	img_help settbl 0 4
	if( @ == 3 )	img_help settbl 0 14
	if( @ == 4 )	img_help settbl 0 16
	img_help setid 0
	img_help disp 1

#btn_yes.UNFOCUS
	img_yes_box[@] setid 0
	img_yes_word[@] setid 0
	img_help disp 0

#btn_yes.PUSH_L
	img_yes_box[@] setid 3
	img_yes_word[@] setid 3
	if( @ == 0 )	\204 = 1
	if( @ == 1 )	\205 = 1
	if( @ == 2 )	\206 = 1
	if( @ == 3 )	\211 = 1
	if( @ == 4 )	\212 = 1
	call SET_YESNO_BUTTON

#btn_yes.RELEASE_L
	img_yes_box[@] setid 2
	img_yes_word[@] setid 2


// 文字の影タイプ
#btn_shadow.FOCUS
	img_shadow_box[@] setid 2
	img_shadow_word[@] setid 2

	// ヘルプ表示
	if( @ == 0 )	img_help settbl 0 6
	if( @ == 1 )	img_help settbl 0 7
	img_help setid 0
	img_help disp 1

#btn_shadow.UNFOCUS
	img_shadow_box[@] setid 0
	img_shadow_word[@] setid 0
	img_help disp 0

#btn_shadow.PUSH_L
	img_shadow_box[@] setid 3
	img_shadow_word[@] setid 3
	if( @ == 0 )	\208 = 1 - \208
	if( @ == 1 )	\209 = 1 - \209
	call SET_SHADOW_BUTTON

#btn_shadow.RELEASE_L
	img_shadow_box[@] setid 2
	img_shadow_word[@] setid 2


// 演出速度
#btn_speed.FOCUS
	img_speed_box[@] setid 2
	img_speed_word[@] setid 2

	// ヘルプ表示
	if( @ == 0 )	img_help settbl 0 8
	if( @ == 1 )	img_help settbl 0 9
	if( @ == 2 )	img_help settbl 0 10
	if( @ == 3 )	img_help settbl 0 11
	if( @ == 4 )	img_help settbl 0 12
	img_help setid 0
	img_help disp 1

#btn_speed.UNFOCUS
	img_speed_box[@] setid 0
	img_speed_word[@] setid 0
	img_help disp 0

#btn_speed.PUSH_L
	img_speed_box[@] setid 3
	img_speed_word[@] setid 3
	\210 = @
	call SET_EFF_SPEED_BUTTON

#btn_speed.RELEASE_L
	img_speed_box[@] setid 2
	img_speed_word[@] setid 2


// メッセージ速度スライダー
#sl_mes.FOCUS
	// ヘルプ表示
	img_help settbl 0 100
	img_help setid 0
	img_help disp 1

#sl_mes.UNFOCUS

#sl_mes.SCRL_P
	@ getpos 850
	\200 = 10 - $850
	call SET_CONFIG
	call SET_SLIDER_NUM
	call STRLAYOUT
	call DRAW_SAMPLE_MESSPEED


// オート速度スライダー
#sl_auto.FOCUS
	// ヘルプ表示
	img_help settbl 0 101
	img_help setid 0
	img_help disp 1

#sl_auto.UNFOCUS
	img_help disp 0

#sl_auto.SCRL_P
	@ getpos 850
	\201 = 10 - $850
	call SET_CONFIG
	call SET_SLIDER_NUM
	call GET_CONFIG		// オート速度の詳細設定を取得するために設定を再取得する
	call STRLAYOUT
	call DRAW_SAMPLE_AUTOSPEED


// ウィンドウ不透明度スライダー
#sl_wndalpha.FOCUS
	// ヘルプ表示
	img_help settbl 0 102
	img_help setid 0
	img_help disp 1

#sl_wndalpha.UNFOCUS
	img_help disp 0

#sl_wndalpha.SCRL_P
	@ getpos 850
	\207 = $850
	call SET_CONFIG
	call SET_SLIDER_NUM


// 各種ボリュームスライダー
#sl_volume.FOCUS
	// ヘルプ表示
	if( @ == 0 )	img_help settbl 0 103
	if( @ == 1 )	img_help settbl 0 104
	if( @ == 2 )	img_help settbl 0 105
	if( @ == 3 )	img_help settbl 0 106
	img_help setid 0
	img_help disp 1

#sl_volume.UNFOCUS
	img_help disp 0

#sl_volume.SCRL_P
	@ getpos 850
	if( @ < 3 )
		\(213+@) = $850
	else
		\217 = $850
	endif
	call SET_CONFIG
	call SET_SLIDER_NUM


// システム系ボタン
#btn_sys.FOCUS
	@ setid 2

	// ヘルプ表示
	if( @ == 0 )	img_help settbl 0 200
	if( @ == 1 )	img_help settbl 0 201
	img_help setid 0
	img_help disp 1

#btn_sys.UNFOCUS
	@ setid 0
	img_help disp 0

#btn_sys.PUSH_L
	@ setid 3
	if( @ == 0 )
		// RESETボタン
		next CONFIRM_RESET	// リセット確認処理へ
	else
		// EXITボタン
		next EXIT
	endif



///////////////////////////
// リセット確認
#CONFIRM_RESET
	$860 = 2
	execfes conf
	wait 1
	next CONFIRM_RESET_WAIT


#CONFIRM_RESET_WAIT
	if( _EXITCODE_ == 1 )
		endfes
		call RESET
		next WAIT
	endif
	if( _EXITCODE_ == 0 )
		endfes
		next WAIT
	endif


///////////////////////////
// リセット処理
#RESET
	// 文章表示速度
	\200 = 4

	// オート速度
	\201 = 4

	// オートの時、オートスピードに関わらず音声再生が終了するまで待つか
	\204 = 1

	// 既読メッセージの瞬間表示
	\205 = 1

	// 選択肢後もオートを継続するか
	\206 = 1

	// メッセージウィンドウの不透明度
	\207 = 90

	// 文字の影（影）
	\208 = 1

	// 文字の影（縁）
	\209 = 1

	// 演出速度
	\210 = 0

	// 演出カット
	\211 = 0

	// ドラマチックモード
	\212 = 0

	// ボリューム−マスター
	\213 = 100

	// ボリューム−BGM
	\214 = 70

	// ボリューム−効果音
	\215 = 90

	// ボリューム−音声
	\216 = 100

	// ボリューム−音声再生時のBGMボリューム
	\217 = 55

	// 設定を反映
	call SET_YESNO_BUTTON		// Yes/Noボタンの設定
	call SET_SHADOW_BUTTON		// 影タイプボタンの設定
	call SET_EFF_SPEED_BUTTON	// 演出速度ボタンの設定
	call SET_SLIDER				// スライダー系の設定

	// 数値設定
	call SET_SLIDER_NUM

	// 設定適用
	call SET_CONFIG


///////////////////////////
// サンプル文章設定
#STRLAYOUT
	str_sample reset
	str_sample layout vdraw 1			// VRAMにも描画するか
	str_sample layout size 16			// フォントサイズ
	str_sample layout margin 0 0 0 0	// 上下左右のマージン
	str_sample[0] layout frame \200		// 文字スクロール速度
	str_sample[1] layout frame 9


///////////////////////////
// メッセージ速度を描画
#DRAW_SAMPLE_MESSPEED
	str_sample[0] clear			// 一度文章を消して...
	str_sample[0] str $str150	// 文章を再設定して...
	str_sample[0] draw -1		// 描画開始(-1を設定すると全文表示)
	// 次の更新時間を算出
	// 更新時間 = [現在時間] + [文字速度] * [文字数]
	\300 = _FRAME_ + \200 * 8


///////////////////////////
// オート速度を描画
#DRAW_SAMPLE_AUTOSPEED
	str_sample[1] clear
	str_sample[1] str $str151
	str_sample[1] draw -1
	// 次の更新時間を算出
	// 更新時間 = [１文字あたりの待ち時間] * [文字数] * [１秒あたりのフレーム数] / 100
	\301 = 8 * \203 * 60 / 100
	// 更新時間 += [基本待ち時間] * [１秒あたりのフレーム数] / 10 + [現在時間]
	\301 += \202 * 60 / 10 + _FRAME_


