/*
	画面スクリプトサンプル
	Ｙｅｓ／Ｎｏ確認メッセージ
*/

#INCLUDE
	motion.h

#PRELOAD	// 先読みファイル定義 (イメージのみ)
	sys_confirm

#DEFINE
	PLANE		pl		// プレーン
	IMAGE		bg		// 背景
	IMAGE		mes		// 文章画像
	BUTTON		btn[2]	// Yes/Noボタン


#OBJECT	SIZE		VRAM		PRI		DISP	BASE		POS
pl		1280,720	1536,832	30000	0		640,360		640,360

#OBJECT	FILE		ID.0	PRI		PL	DISP
bg		sys_confirm	1		1000	pl	1
mes		sys_confirm	10		1001	pl	1

#OBJECT	FILE		ID.0	ID.1	ID.2	ID.3	PRI		PL	DISP	ENABLE
btn[0]	sys_confirm	100		200		300		400		61000	pl	1		0		// YES
btn[1]	sys_confirm	101		201		301		401		61100	pl	1		0		// NO


// キーボード・ジョイパッド入力設定
#KEYBLOCK	1	//(w,h)	上,下,左,右
0				2,1		-1,-1,-1,-1

#OBJECT		KEYBLOCK	// (block,x,y)
btn[0]		0,0,0
btn[1]		0,1,0



///////////////////////////
// スタート
#START
	// キー入力による演出スキップをOFF
	keyskip 0
	wait

	// ベースボタンのプライオリティを上げて
	//親スクリプトのボタンを効かないようにする
	basebtnpri 60000

	// 文章を設定
	mes settbl 0 $860+10	// IDテーブル0に画像IDを設定
	mes setid 0				// ↑だけだとまだ反映されない。ID:0を使用するよう、再設定で
							// 表示が変わる
	mes disp 1				// 表示

	// ボタンを表示
	btn disp 1

	wait

	// スケールで小さくしておく
	pl scale 0% 0%
	wait

	// プレーン表示
	pl disp 1

	// 元のサイズにする
	pl mscale 5 100% 100%
	wait

	// ボタンのあるプレーンのベース位置が0,0以外だと、キー入力時ど動作や
	// カーソル自動移動が正常に動作しないため、拡縮演出後に0,0に戻す
	pl pos 0 0
	pl base 0 0
	wait

	// ボタン有効化
	btn enable 1

	// カーソルがボタン以外の場所にあった時に矢印キーが押された場合の
	// 移動先ボタンの設定
	btn[0] noact 1

	// カーソル自動移動（『はい』に移動）
	automove btn[0]

	// 入力待ちへ
	next WAIT


///////////////////////////
// 入力待ち
#WAIT
	if( _CLICK_R_ != 0 )
		// 右クリックが押されたらキャンセル扱いにする
		\0 = 1
		next EXIT
	endif


///////////////////////////
// 終了処理
#EXIT
	// ボタンを無効化
	btn enable 0

	// フェードアウト
	pl fade 10 255 0
	wait

	exit 1-\0	// \0=1ならYES 0ならNO にして、終了コードとする

	// 空ループへ
	next SLEEP


///////////////////////////
// 終了後の空ループ
#SLEEP



///////////////////////////
// ボタン処理
#btn.FOCUS		// カーソルが乗った
	@ setid 2	// ボタン色をフォーカス状態にする

#btn.UNFOCUS	// カーソルが離れた
	@ setid 0	// ボタン色を通常状態に戻す

#btn.PUSH_L	// 決定された
	@ setid 3	// ボタン色を押下状態にする

	\0 = @		// 押されたボタン番号を退避
	next EXIT	// 終了処理へ

